Beispiele
für die FLEX-Manipulationsbefehle

%=#uX9x var "x " zc\if ="x  " end\sho iv\exec%In jedem dieser Beispiele (außer 10.+11.) wird zuerst eine Variable #uab mit einem Text belegt. Das geschieht, indem einfach die Variable samt Inhalt hingeschrieben wird! 
Dann wird mit einem var-Befehl daraus ein Abschnitt ausgewählt. Der wird dann angezeigt. Statt des Befehls mes kann z.B. ein ins-Befehl gegeben werden, um den ausgewählten Abschnitt in eine Kategorie oder Variable zu kopieren! 
Wenn man statt  var #uab(...) nur schreibt  var (...), wird der momentane Inhalt der internen Variablen genommen und die Manipulation darauf angewendet. Dies kann man bei den `Freien Variablen` anwenden, denn bei diesen funktioniert ein hintergesetzter Manipulationsbefehl nicht. 
ACHTUNG: Zum Ausprobieren: jeweils Schreibmarke auf die Befehlszeile setzen, dann Alt+9

  1a. Abschnitt hinter dem 4. Zeichen, insges. 3 Zeichen 
#uab abcdefghijk\var #uab(4,3)\mes 

  1b. Die letzten 5 Zeichen  [ab V28.8.1]
#uab abcdefghijk\var #uab(-5,0)\mes 

  2a. Den Teil hinter der Zeichenkombination  "cd" 
#uab abcdefg\var #uab(b"cd")\mes 

  2b. Den Teil hinter dem ersten Auftreten von :, / oder - nehmen 
#uab abc-def:ghi\var #uab(b"[:/-]")\mes 

  3. Abschnitt hinter dem Zeichen "f", 4 zeichen lang 
#uab abcdefgabcdefg\var #uab(b"f" 0,4)\mes 

  4. Zuerst hinter "b" gehen, dann Abschnitt hinter "f" nehmen, Ende vor "EFG" 
#uab abcdefgABCDEFGHI\var #uab(b"b" b"f" e"EFG")\mes 

  5. Gesamten Text von #uab, aber vorn alle Zeichen 3,2,4 oder 1 beseitigen  
      (Achtung: f und F werten die Zeichen einzeln aus, nicht als Zeichenfolge!)   
#uab 123454321abcdefg\var #uab(f"3241")\mes 

  6. Gesamten Text von #uab, aber hinten alle Zeichen f, g oder e beseitigen 
#uab 12345abcgfdefg\var #uab(F"fge")\mes 

  7. Von #uab hinten den Teil wegnehmen, der mit "de" anfängt  
      (Text bleibt unverändert, wenn "de" nicht vorkommt) 
#uab 12345abcdefg\var #uab(t"de")\mes 

  8. Von #uab hinten den Teil nehmen, der hinter "34" anfängt  
      (Ergebnis ist leer, wenn "34" nicht vorkommt) 
#uab 12345abcdefg\var #uab(T"34")\mes 

  9. Den Teil hinter der Zeichenkombination  "CD" nehmen, aber nur wenn diese vorkommt 
      (Wenn nicht, dann alles) 
#uab abcdefg\var #uab(B"CD")\mes 
#uab abCDefg\var #uab(B"CD")\mes 

10. Vom Namen der Exportdatei nur den eigentlichen Namen zeigen (hinter dem letzten \)  
      (Problem dabei: Manip.Befehl T nur anwenden, wenn wirklich \ vorkommt!) 
var E\if %%\\%% var (T"\\")\mes 
Erklärung: mit var E wird erst der Name der Exp.Datei in die iV kopiert. Darauf wird if %%\\%% angewendet, um zu schauen, ob ein \ darin vorkommt. 
(Wenn der \ als Zeichen gemeint ist, und nicht als Befehlstrenner, muß er doppelt angegeben werden) 
Der nachfolgende Befehl var (T"\\") wird wegen des if ... nur ausgeführt, wenn wirklich ein \ vorkommt; wenn nicht, bleibt die Zeichenfolge unverändert.

11. In #dts steht das Tagesdatum in der Form JJJJMMTT. Umwandeln in TT.MM.JJJJ, wobei es nicht z.B. 05.07.2005 heißen soll, sondern 5.7.2005! Davor soll stehen "Heute ist der "
var "Heute ist der " #dts(6,2 f"0") "." #dts(4,2 f"0") "." #dts(0,4)\mes 

12. In #uxy steht das Datum in der Form T.M.JJJJ, also z.B.  1.2.1977. Man will daraus die Form JJJJ-MM-TT machen, 
     also  1977-02-01. Das geht so: 
#uxy 1.2.1977\var #uxy(b"." b".") "-" #uxy(b"." e"." r2,0) "-" #uxy(e"." r2,0)\mes 

13. Aus dem Anzeigefeld soll die mit  12.  beginnende Zeile herauskopiert und angezeigt werden. Dazu nutzt man den Befehl  file, der das gesamte Anzeigefeld in eine Datei schreibt, und diese liest man mit  var Fdateiname  in die iV ein:
file anzeige.txt\var Fanzeige.txt\var (b"^J12. " e"^M")\ansi\mes
Erklärung: mit  var (b"12. " e"^M") wird eingelesene Anzeigetext, der nun in der iV steht, nach 12. durchsucht, und der dahinter stehende Text beim Zeichencode 13 (mit ^M codiert) beendet; eine Zeile beginnt in einer .txt-Datei immer direkt hinter einem Code 10 (dafür steht ^J).

?Freien Variablen=h xfreevar